sys-kernel/libre-kernel, virtual/dist-kernel: Linux-libre 5.15.83

sys-kernel/libre-kernel/Manifest

@@ -5,5 +5,5 @@ DIST linux-libre-5.15.77-gnu.tar.xz 119696132 BLAKE2B c4a16a82a886c82954480f6063
 DIST linux-libre-5.15.77-gnu.tar.xz.sign 195 BLAKE2B ba41ae8c34c9f53a9a9b7bb8ec67c990c4a30168bcab79b7deb15b99615aa257f4dd48a7ff59db40b6d32ce87b155aa5a56eb663c999f1c91d04441bc8db39aa SHA512 988464375ee5f41fcac07f0ecaa1194e9332cfa1f134f6b1427ddfadf31bbd71f3d51efa8ccc87a927011bc5d9e95791cdf0399a9464b8e5d4f85e83acab8e3c
 DIST linux-libre-5.15.80-gnu.tar.xz 119711916 BLAKE2B e86e7e77ad8268c5fb442f993f4775188541aa6029bcb15925bad23921766c2d5fd9cd04f991c59f98700af207950eccf24459e8b339f852f9ce4a87691987b8 SHA512 d249b5d258156a25a3892138a7dd59b51e238997827979320e382dbd55c93c6ab2b890b65a6e671cee3bd61af567202413440e8a39d5f7ad628dc80b321c2e60
 DIST linux-libre-5.15.80-gnu.tar.xz.sign 195 BLAKE2B ff3d6479d9ecd99572a60bd9d0dd0eaa8913e455b877c5b30666a8b73f69b51762f87aab2b529629688ae5f5f572858e6d472e5f872920d70a57d4ff372f212e SHA512 caa2e50ce8d3210339fb4ca191d9ad8dce83622e8bc190d7597d685b89994ea87a8462b496a07aba3ba2bd37b464845dd7b5799acf350dd4a315ec5918866332
-DIST linux-libre-5.19.17-gnu.tar.xz 124362148 BLAKE2B d62685af7373f5eaeb45c3917fec5df6bec43742ded71e4fa91ac995b09a29bfbf50ffceb232749624497280b4ba3d092a84856f676ac8fe09924b1d6027c870 SHA512 a491a96d26fd88cc1fadc06fcb363b4a35f03b38bb62c8adbc6e0bf2fc136655978f19a438d83efedcaa1a8142f35c249a3e4c7256f1122c436d55ac4d1cf432
+DIST linux-libre-5.15.83-gnu.tar.xz 119716144 BLAKE2B 8c5f14017687f5af9f82c4c85293436633f3ce31a3592346ae7f57f5e2250a26630dbd3b05eb354e467b93c5ddd6d245e35448ceb27cf030b268d821e65baed1 SHA512 82ec18c9584ea81c2fced0b1f9706ff97386aba32acca3e9ef6432abeed1178618de4afe8dfd9ccab2b2854b44fc61c6ab1f6c7707a521e36b92a9198797e52b
-DIST linux-libre-5.19.17-gnu.tar.xz.sign 195 BLAKE2B 84d7b28ce97bb63de45b65206f6ebb6b3ee1c86858ca1220f6827210160ef160a0888682ef290b07e102586d18bae900ec5605281c4e31ee74e5c99ea0c0885f SHA512 22848fa4ae7ff33affc825be0d922cccfb59e2f1740c080ee0156d1077ef53cb38eb1314e7a44fc96406da6b3bf193971c032f5d33c39f14819f421333b6def4
+DIST linux-libre-5.15.83-gnu.tar.xz.sign 195 BLAKE2B b5571b9b528c8108a9c46b7e1fd3693a3f293a499eaa69ebaab5442a2419f81b05f1bcc647e441a3fc87b74dfe38d258e4ed54fa91a1646af67bc090b5cd88b6 SHA512 a4cbe554176646445756dcf7d1cb720dd53f2dec62e907c817a1f4a450983b4c002408c7e277ed8522136223c1ba1bc486711139cca5d9ae5e030023cc18dfaa

sys-kernel/libre-kernel/libre-kernel-5.15.83.ebuild

@@ -0,0 +1,150 @@
+# Copyright 2020-2022 Gentoo Authors, projectmoon
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-build verify-sig
+
+BASE_VER="$(ver_cut 1).$(ver_cut 2).$(ver_cut 3)"
+RESTRICT="mirror"
+
+# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
+CONFIG_VER=5.15.19
+CONFIG_HASH=ec69da7a42b5b7c3da91572ef22097b069ddbd01
+GENTOO_CONFIG_VER=g1
+
+DESCRIPTION="GNU Linux-libre kernel built from upstream sources"
+HOMEPAGE="https://www.fsfla.org/ikiwiki/selibre/linux-libre/"
+SRC_URI+="
+	https://git.agnos.is/projectmoon/projectmoon-overlay-files/media/branch/main/sys-kernel/libre-kernel/linux-libre-${BASE_VER}-gnu.tar.xz
+	https://github.com/projg2/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
+		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
+	verify-sig? (
+		https://git.agnos.is/projectmoon/projectmoon-overlay-files/media/branch/main/sys-kernel/libre-kernel/linux-libre-${BASE_VER}-gnu.tar.xz.sign
+	)
+	amd64? (
+		https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-x86_64-fedora.config
+			-> kernel-x86_64-fedora.config.${CONFIG_VER}
+	)
+"
+
+# Workdir is named linux-PV.
+MY_P=linux-${PV}
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="amd64"
+IUSE="debug"
+
+BDEPEND="
+	debug? ( dev-util/pahole )
+	verify-sig? ( sec-keys/openpgp-keys-linux-libre )
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linux-libre.asc
+
+pkg_pretend() {
+	if has_version -d sys-kernel/linux-firmware[redistributable]; then
+		ewarn "sys-kernel/linux-firmware was found installed on your system,"
+		ewarn "but it is configured to install non-Free firmware files."
+		ewarn "The non-Free firmware files may be required for some hardware"
+		ewarn "work. The Linux-libre kernel cannot load non-Free firmware."
+		ewarn "To install only the Free firmware, set the -redistributable"
+		ewarn "USE flag on sys-kernel/linux-firmware."
+
+		if use initramfs; then
+			elog
+			elog "If you decide to change or remove linux-firmware later, you"
+			elog "can rebuild the initramfs via issuing a command equivalent to:"
+			elog
+			elog "    emerge --config ${CATEGORY}/${PN}:${SLOT}"
+		fi
+	else
+		if ! has_version -d sys-kernel/linux-firmware; then
+			ewarn "sys-kernel/linux-firmware[-redistributable] not found installed"
+			ewarn "on your system. This package provides various firmware files that"
+			ewarn "may be needed for your hardware to work.  If in doubt, it is recommended"
+			ewarn "to pause or abort the build process and install it before"
+			ewarn "resuming."
+
+			if use initramfs; then
+				elog
+				elog "If you decide to install linux-firmware later, you can rebuild"
+				elog "the initramfs via issuing a command equivalent to:"
+				elog
+				elog "    emerge --config ${CATEGORY}/${PN}:${SLOT}"
+			fi
+		fi
+	fi
+}
+
+src_unpack() {
+	if use verify-sig; then
+		FILE="${DISTDIR}"/linux-libre-${PV}-gnu.tar.xz
+		SIGFILE="${DISTDIR}"/linux-libre-${PV}-gnu.tar.xz.sign
+		verify-sig_verify_detached $FILE $SIGFILE
+	fi
+
+	default
+}
+
+src_prepare() {
+	default
+
+	local biendian=false
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		arm)
+			return
+			;;
+		arm64)
+			cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		hppa)
+			return
+			;;
+		ppc)
+			# assume powermac/powerbook defconfig
+			# we still package.use.force savedconfig
+			cp "${WORKDIR}/${MY_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
+			;;
+		ppc64)
+			cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		x86)
+			cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	sed -i 's/EXTRAVERSION = -gnu/EXTRAVERSION = /' "${S}"/Makefile || die 'could not remove EXTRAVERSION'
+	local myversion="-gnu-dist"
+	echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
+	local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
+
+	local merge_configs=(
+		"${T}"/version.config
+		"${dist_conf_path}"/base.config
+	)
+	use debug || merge_configs+=(
+		"${dist_conf_path}"/no-debug.config
+	)
+
+	# this covers ppc64 and aarch64_be only for now
+	if [[ ${biendian} == true && $(tc-endian) == big ]]; then
+		merge_configs+=( "${dist_conf_path}/big-endian.config" )
+	fi
+
+	kernel-build_merge_configs "${merge_configs[@]}"
+}

virtual/dist-kernel/dist-kernel-5.15.83.ebuild

@@ -0,0 +1,20 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Virtual to depend on any Distribution Kernel"
+HOMEPAGE=""
+SRC_URI=""
+
+LICENSE=""
+SLOT="0/${PV}"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~ppc ppc64 x86"
+
+RDEPEND="
+	|| (
+		~sys-kernel/gentoo-kernel-${PV}
+		~sys-kernel/gentoo-kernel-bin-${PV}
+		~sys-kernel/vanilla-kernel-${PV}
+		~sys-kernel/libre-kernel-${PV}
+	)"